有名なところから。
同じフレームの別レイヤーに記述されたASは上から全て繋げられることになります。
昔はこれを利用して目的ごとにレイヤー分けしてたんですが、最近はやめました。
検索しにくいってのが一番ネックです。
アクションウインドウに長々と書かなければいけない場合は、includeを使って外部ファイルに記述しちゃうべきだと思います。

今回のメインのお話です。
タイムラインのASは実行順序が自動的に変化するものがあります。
初心者の方はfunctionがどういう条件で実行されるの？と不思議に思っている人がいます。
同じフレームにあればいいのか、命令前に定義されていればいいのか・・・。
先にこれを答えておくのですが、functionは変数と同じ扱いです。
定義された場所以降使用することができ、何回も定義されるとそのたびに上書きされます。
、と聞いて、あれれ？と思った人がいるでしょう。

testA();
function testA() {
	  trace("A");
}

こんな処理の場合、testAが定義される前に、呼び出せて「A」と表示されるのです。
でも、関数の宣言ってもう１個ありましたよね？○○=function(){～～}ってやつ。
ちょっとこれでテストしてみましょう。

testA();
testA = function () {
	trace("A");
}

なんと、これでは「A」と表示されない、つまり関数が呼び出せていないのです。
えー、なんでー？。
次にこんなことをしてみましょう。

testA = function () {
	trace("A-1");
};
function testA() {
	trace("A-2");
}
testA();

予想は？２番目の関数宣言が上書きされて「A-2」となるでしょうか？
正解は「A-1」が表示されます。

function testA() {
	trace("A-2");
}
testA = function () {
	trace("A-1");
};
testA();

逆にしてみても結果は同じ、「A-1」です。

何がおきているのかというと、「function なんとか～」　というASは、自動的にそのフレームの一番最初に移動しているのです。
つまり、同じフレームであれば宣言する前に関数を使えるのは、実は勝手にその前に宣言されちゃっているのです。
移動はレイヤーも飛び越え、同じフレームの最初で宣言されるようです。
これを知ると色々と宣言上の問題を回避できます。
関数の中で関数の宣言をしてわけわからないことになってた人がいますがｗこれを理解できれば対処できるはずです。

ちなみに移動するfunctionは平文にあるものに限ります。

testA();
if (true) {
	function testA() {
		trace("A");
	}
}

これは実行されません。

Flash職人が２・３番目によく使うであろうgotoAndPlay()なのですが、実はこれにも実行順序に注意が必要な面があります。
まず、有名な例ですがフレームの描画タイミングを１個スキップします。

// １フレーム目
trace("1");

// ２フレーム目
gotoAndPlay(1);

この場合、１フレーム目が途切れることなく実行されます。
１フレーム目→画面描画→２フレーム目→１フレーム目→画面描画・・・
というわけですね、２フレーム目は描画されないわけです。
ですので、もし

// １フレーム目
gotoAndPlay(2);

// ２フレーム目
gotoAndPlay(1);

こう記述すると画面描画されることなくずっと１フレーム目と２フレーム目の無限ループが発生してFlashがフリーズします（マジです、実験するときは気をつけましょう）

さて、ここからが本題。

// １フレーム目
trace("1-1");
gotoAndPlay(2);
trace("1-2");

// ２フレーム目
trace("2")
stop();

さあ、何が表示されるでしょうか。
「1-1」→「2」となって、「1-2」は消えてしまう？
それとも「1-1」→「2」→「1-2」という風に、残りもちゃんと実行される？
正解は「1-1」→「1-2」→「2」です。
なんで？？
じゃあこれは？

// １フレーム目
trace("1-1");
gotoAndPlay(2);
trace("1-2");
gotoAndPlay(3);
trace("1-3");

// ２フレーム目
trace("2")
stop();

// ３フレーム目
trace("3")
stop();

正解を書いてしまえば、「1-1」→「1-2」→「1-3」→「2」→「3」です
gotoAndPlay()やgotoAndStop()は呼ばれても直ちに処理されず、フレームの処理が全て終了してから順に実行されます。
ですから同じフレームに２個以上のgotoAndPlay()やgotoAndStop()がある場合は気をつけましょう。
とっても処理がややこしいのですが、次のreturn文を使用することで制御が楽になることがあります。

なんとフレームアクションでいきなりreturn文を記述することができます。

trace("A");
return;
trace("B");

この例では「A」しか表示されなくなります。
returnはフレームで使用すると、そのフレームのASをそこで強制終了にします。
この強制終了はさっきのgotoAndPlay()に効果があります。

// １フレーム目
trace("1-1");
gotoAndPlay(2);
return;
trace("1-2");
gotoAndPlay(3);
trace("1-3");

// ２フレーム目
trace("2")
stop();

// ３フレーム目
trace("3")
stop();

この場合、表示は「1-1」→「2」です。
gotoAndPlay(2)を記述した後のreturnでフレームが終わったことにされ、gotoAndPlay(2)が直ちに実行されます。
残りの処理は全て切り捨てられるわけです。

ちなみに

testA();
return;
function testA() {
	  trace("A");
}

これは「A」が表示されます。
functionはreturnよりも上へ移動してしまうために、returnの影響を受けません。